home *** CD-ROM | disk | FTP | other *** search
/ The Best of Select: Games Special 7 / TboS Games Special 7.iso / viruskil / tbav703 / install.bat < prev    next >
DOS Batch File  |  1996-07-09  |  11KB  |  358 lines
  1. @echo off
  2. echo off
  3. cls
  4. echo        --- Thunderbyte Anti-Virus installation batch program ---
  5. echo.
  6.  
  7. rem     * Make sure that we can find the utilities in the current directory
  8. if not exist TBSCAN.EXE goto error1
  9.  
  10. rem     * Find out if we are upgrading a previous version in the current dir
  11. if exist TBSTART.BAT goto pathexists
  12.  
  13. rem     * Make sure that the user specified a destination path
  14. if %1X==X goto error2
  15.  
  16. rem     * Make sure the target path exists or can be created
  17. if exist %1\nul goto pathexists
  18. md %1
  19. if not exist %1\nul goto error3
  20. :pathexists
  21.  
  22. rem     * Make sure user did not type something like 'C:' :-)
  23. if exist %1\CONFIG.SYS goto error5
  24.  
  25. echo Please read the License.Doc file. By using the TBAV package you
  26. echo agree with our license agreement. You can print the License.Doc
  27. echo file by typing the following command on the DOS command line:
  28. echo    Copy License.Doc Lpt1
  29. echo Press Ctrl-C to abort this installation batch file, or
  30. pause
  31.  
  32. echo.
  33. echo This installation batch file of the shareware version of TBAV
  34. echo is not the same as the full featured installation program of the
  35. echo commercial version of TBAV. (The main reason for the omission of
  36. echo the installation program is to save disk space and to minimize
  37. echo download time). Therefore the installation procedure might
  38. echo differ from the procedure described in the manual.
  39. echo.
  40.  
  41. rem     * If TbScanX is active, de-activate it.
  42. if not exist SCANX goto notres
  43. if exist %1\tbscanx.exe %1\tbscanx /off
  44.  
  45. :notres
  46. rem     * Copy the TBAV utilities if necessary
  47. if exist dummy.tst del dummy.tst >nul
  48. if exist %1\dummy.tst del %1\dummy.tst >nul
  49. echo TEST >%1\dummy.tst
  50. if exist dummy.tst goto filesexists
  51. if not exist %1\dummy.tst goto error4
  52. echo TbSetup will now delete the Anti-Vir.Dat file of a previous
  53. echo TBAV version if it exists in directory %1
  54. pause
  55. rem     * If Anti-Vir.Dat already exists and is hidden, delete it...
  56. tbsetup %1 remove
  57. cls
  58. echo Copying files. Please wait...
  59. copy addendum.doc %1 >nul
  60. copy agents.doc %1 >nul
  61. copy anti-vir.dat %1 >nul
  62. copy appnotes.doc %1 >nul
  63. copy esass.pgp %1 >nul
  64. copy file_id.diz %1 >nul
  65. copy install.bat %1 >nul
  66. copy license.doc %1 >nul
  67. copy makeresc.bat %1 >nul
  68. copy no_vsum.doc %1 >nul
  69. copy register.exe %1 >nul
  70. copy report.doc %1 >nul
  71. copy security.doc %1 >nul
  72. copy tbav.doc %1 >nul
  73. copy tbav.exe %1 >nul
  74. copy tbav.lng %1 >nul
  75. copy tbav.msg %1 >nul
  76. copy tbcheck.exe %1 >nul
  77. copy tbclean.exe %1 >nul
  78. copy tbdel.com %1 >nul
  79. copy tbdisk.exe %1 >nul
  80. copy tbdriver.exe %1 >nul
  81. copy tbdriver.lng %1 >nul
  82. copy tbfile.exe %1 >nul
  83. copy tbgensig.exe %1 >nul
  84. copy tbkey.exe %1 >nul
  85. copy tblog.exe %1 >nul
  86. copy tbmem.exe %1 >nul
  87. copy tbscan.eci %1 >nul
  88. copy tbscan.exe %1 >nul
  89. copy tbscan.lng %1 >nul
  90. copy tbscan.sig %1 >nul
  91. copy tbscanx.exe %1 >nul
  92. copy tbsetup.dat %1 >nul
  93. copy tbsetup.exe %1 >nul
  94. copy tbutil.exe %1 >nul
  95. copy tbutil.lng %1 >nul
  96. copy veldman.pgp %1 >nul
  97. copy tbav.faq %1 >nul
  98. copy tbmon.com %1 >nul
  99. copy whatsnew.* %1 >nul
  100. if %_4ver%x==x copy descript.ion %1 >nul
  101.  
  102. :filesexists
  103. del %1\dummy.tst >nul
  104. if not exist %1\docs.exe goto nopack
  105. %1\docs -o %1
  106. del %1\docs.exe >nul
  107. :nopack
  108.  
  109. rem     * DOS has no interactive batch file commands,
  110. rem     * so we create a special program to solve that!
  111. rem     * the 'garbage' in the echo command is program code
  112. rem     * to read a key into an errorlevel, the program code
  113. rem     * will be copied into an executable file.
  114. echo ═êα╧┤L═! >%1\ask.com
  115.  
  116. echo.
  117. echo TbSetup will now generate or update the Anti-Vir.Dat file
  118. echo of the directory %1
  119. pause
  120. rem     * create or update the Anti-Vir.Dat records of the TBAV utilities
  121. %1\TBSETUP %1
  122.  
  123. cls
  124. rem     * do not overwrite an existing TBAV setup.
  125. if exist %1\TBSTART.BAT goto upgrade
  126.  
  127. echo.
  128. echo The Thunderbyte Anti-Virus utilities have been copied to the destination
  129. echo directory. It is recommended to read the documentation of TBAV thoroughly
  130. echo and to make a customized setup. One of the advantages of the Thunderbyte
  131. echo Anti-Virus utilities is flexibility and the possibility to configure
  132. echo them to suit your needs in an optimal way.
  133. echo.
  134. echo This installation batch file helps you to setup the utilities in their
  135. echo most standard and non-customized way.
  136. echo Do you want to continue? (Y/n)
  137. %1\ask
  138. if not errorlevel 1 goto nosetup
  139.  
  140. rem     * make a backup of the AUTOEXEC.BAT file!
  141. echo.
  142. echo Backing up C:\AUTOEXEC.BAT to C:\AUTOEXEC.ORG...
  143. copy c:\autoexec.bat c:\autoexec.org >nul
  144.  
  145. rem     * create a TBSTART.BAT file in the TBAV directory.
  146. echo @echo off >%1\TBSTART.BAT
  147. echo echo off >>%1\TBSTART.BAT
  148.  
  149. echo.
  150. echo For easy access of the TBAV utilities it is recommended to put them
  151. echo into your PATH environment variable.
  152. echo Do you want to add %1 to your PATH statement? (Y/n)
  153. %1\ask
  154. if not errorlevel 1 goto dosetup
  155. rem     * add the PATH statement to the end of the AUTOEXEC.BAT file.
  156. echo PATH=%%PATH%%;%1 >>C:\AUTOEXEC.BAT
  157.  
  158. :dosetup
  159. echo.
  160. echo TbSetup will now process your drives to generate the Anti-Vir.Dat files.
  161. pause
  162. rem     * process the rest of the machine, but do not touch existing information!
  163. %1\TbSetup NewOnly AllDrives
  164.  
  165. :tbdriver
  166. cls
  167. echo.
  168. echo The TBAV package contains some utilities that can be installed in the memory
  169. echo of your PC. Do you want to add them to your AUTOEXEC.BAT file? (Y/n)
  170. %1\ask
  171. if not errorlevel 1 goto autoscan
  172. rem     * create a TBSTART.BAT file in the TBAV directory.
  173. echo %1\TbDriver >>%1\TBSTART.BAT
  174.  
  175. echo.
  176. echo TBSCANX is a memory resident virus scanner.
  177. echo Do you want to install it? (Y/n)
  178. %1\ask
  179. if not errorlevel 1 goto tbcheck
  180. rem     * add the TbScanX statement to the TBSTART.BAT file.
  181. echo %1\TbScanX EMS XMS >>%1\TBSTART.BAT
  182.  
  183. :tbcheck
  184. echo.
  185. echo TBCHECK is a memory resident integrity checker.
  186. echo Do you want to install it? (Y/n)
  187. %1\ask
  188. if not errorlevel 1 goto tbmem
  189. rem     * add the TbCheck statement to the TBSTART.BAT file.
  190. echo %1\TbCheck noavok=ab >>%1\TBSTART.BAT
  191.  
  192. :tbmem
  193. echo.
  194. echo TBMEM is a resident memory guard.
  195. echo Do you want to install it? (Y/n)
  196. %1\ask
  197. if not errorlevel 1 goto tbfile
  198. rem     * add the TbMem statement to the TBSTART.BAT file.
  199. echo %1\TbMem >>%1\TBSTART.BAT
  200.  
  201. :tbfile
  202. echo.
  203. echo TBFILE is a resident file guard.
  204. echo Do you want to install it? (Y/n)
  205. %1\ask
  206. if not errorlevel 1 goto autoscan
  207. rem     * add the TbFile statement to the TBSTART.BAT file.
  208. echo %1\TbFile >>%1\TBSTART.BAT
  209.  
  210. :autoscan
  211. echo.
  212. echo Do you want the system to be scanned automatically for viruses every day? (Y/n)
  213. %1\ask
  214. if not errorlevel 1 goto addcall
  215. rem     * add the TbScan statement to the TBSTART.BAT file.
  216. echo %1\TbScan Once AllDrives >>%1\TBSTART.BAT
  217.  
  218. :addcall
  219. if exist C:\TEMP.BAT del C:\TEMP.BAT >nul
  220. echo call %1\TBSTART.BAT >C:\TEMP.BAT
  221. copy /a C:\TEMP.BAT + C:\AUTOEXEC.BAT C:\TEMP2.BAT >nul
  222. copy C:\TEMP2.BAT C:\AUTOEXEC.BAT >nul
  223. del C:\TEMP.BAT >nul
  224. del C:\TEMP2.BAT >nul
  225.  
  226. :ready
  227. echo.
  228. echo Do you want to scan your drives now? (Y/n)
  229. %1\ask
  230. if not errorlevel 1 goto starttbav
  231. %1\TbScan AllDrives
  232.  
  233. :starttbav
  234. cls
  235. :nosetup
  236. echo.
  237. echo It is highly recommended to print the TBAV user manual.
  238. echo You can do this with the following DOS command:
  239. echo    Copy TBAV.DOC Lpt1
  240. echo.
  241. echo If you are upgrading from previous TBAV versions, it is recommended
  242. echo to print the WHATSNEW files and the Addendum.Doc.
  243. echo You can do this with the following DOS command:
  244. echo    Copy WHATSNEW.* Lpt1
  245. echo    Copy ADDENDUM.DOC Lpt1
  246. echo.
  247. echo The menu program TBAV.EXE can be used to read the documentation files.
  248. echo Do you want to start TBAV now? (Y/n)
  249. %1\ask
  250. if not errorlevel 1 goto flush
  251. %1\TBAV
  252. goto end
  253.  
  254. :upgrade
  255. echo.
  256. if exist %1\UserSig.Dat %1\TbGenSig
  257. rem     * Delete all stuff we don't support anymore
  258. echo Install.Bat will delete some obsolete files from previous TBAV
  259. echo versions which are not supported anymore.
  260. echo.
  261. if exist %1\TbScan.Com del %1\TbScan.Com >nul
  262. if exist %1\TbScan.Msg del %1\TbScan.Msg >nul
  263. if exist %1\VirScan.Dat del %1\VirScan.Dat >nul
  264. if exist %1\AddnSigs.Dat del %1\AddnSigs.Dat >nul
  265. if exist %1\ComprSca.* del %1\ComprSca.* >nul
  266. if exist %1\*.AVR del %1\*.AVR >nul
  267. if exist %1\MTE.Doc del %1\MTE.Doc >nul
  268. if exist %1\Washburn.Doc del %1\Washburn.Doc >nul
  269. if exist %1\TbScanX.Com del %1\TbScanX.Com >nul
  270. if exist %1\TbRescue.* del %1\TbRescue.* >nul
  271. if exist %1\TBAV.CFG del %1\TBAV.CFG >nul
  272. if exist %1\TbShell.* del %1\TbShell.* >nul
  273. if exist %1\register.exe ren %1\register.exe reg.exe >nul
  274. if exist %1\register.txt ren %1\register.txt reg.txt >nul
  275. if exist %1\register.* del %1\register.* >nul
  276. if exist %1\reg.exe ren %1\reg.exe register.exe >nul
  277. if exist %1\reg.txt ren %1\reg.txt register.txt >nul
  278. if exist %1\TbGarble.* del %1\TbGarble.* >nul
  279. if exist %1\GetBoot.* del %1\GetBoot.* >nul
  280. if exist %1\Intro.Doc del %1\Intro.Doc >nul
  281. if exist %1\TbSetup.Doc del %1\TbSetup.Doc >nul
  282. if exist %1\TbUtil.Doc del %1\TbUtil.Doc >nul
  283. if exist %1\TbScan.Doc del %1\TbScan.Doc >nul
  284. if exist %1\TbClean.Doc del %1\TbClean.Doc >nul
  285. if exist %1\StackMan.Doc del %1\StackMan.Doc >nul
  286. if exist %1\TbGensig.Doc del %1\TbGensig.Doc >nul
  287. if exist %1\TbDriver.Doc del %1\TbDriver.Doc >nul
  288. if exist %1\TbScanX.Doc del %1\TbScanX.Doc >nul
  289. if exist %1\TbCheck.Doc del %1\TbCheck.Doc >nul
  290. if exist %1\TbMem.Doc del %1\TbMem.Doc >nul
  291. if exist %1\TbFile.Doc del %1\TbFile.Doc >nul
  292. if exist %1\TbDisk.Doc del %1\TbDisk.Doc >nul
  293. if exist %1\TbDel.Doc del %1\TbDel.Doc >nul
  294. if exist %1\Upgrade.Bat del %1\Upgrade.Bat >nul
  295. if exist %1\TBAV.ICO del %1\TBAV.ICO >nul
  296. if exist %1\TBAV.PIF del %1\TBAV.PIF >nul
  297. echo All obsolete TBAV files have been removed.
  298. echo.
  299. if not exist %1\StackMan.Exe goto ready
  300. echo Note: StackMan.Exe is not necessary anymore to solve TBAV problems.
  301. echo StackMan is therefor no longer supplied with the shareware TBAV package.
  302. echo If you do not use StackMan, you can delete it from the TBAV directory.
  303. goto ready
  304.  
  305. :error1
  306. echo Error: Invalid program invocation!
  307. echo.
  308. echo Make sure that you invoke INSTALL.BAT in the directory where the
  309. echo TBAV utilities can be found!
  310. echo.
  311. echo Example: if the TBAV utilities can be found on drive A:, you should type:
  312. echo A: [enter]
  313. echo INSTALL [path] [enter]
  314. goto end
  315.  
  316. :error2
  317. echo Error: No destination path specified!
  318. echo.
  319. echo You have to specify the destination path for the TBAV utilities!
  320. echo Even if the utilities are already in the destination path.
  321. echo.
  322. echo Example:
  323. echo If the TBAV utilities are or should be copied to C:\TBAV, please type:
  324. echo INSTALL C:\TBAV
  325. goto end
  326.  
  327. :error3
  328. echo Error: Unable to creat destination directory %1
  329. echo.
  330. echo Make sure you enter an existing destination path or a path that can be created!
  331. goto end
  332.  
  333. :error4
  334. echo Error: Unable to copy files in directory %1
  335. echo.
  336. echo Disk full? Access denied?
  337. goto end
  338.  
  339. :error5
  340. echo Error: No target directory specified!
  341. echo.
  342. echo Make sure you enter a full destination path!
  343. echo %1 is not sufficient!
  344. echo.
  345. echo Example:
  346. echo If the TBAV utilities are or should be copied to C:\TBAV, please type:
  347. echo INSTALL C:\TBAV
  348. goto end
  349.  
  350. :flush
  351. echo.
  352. echo If you have a disk cache installed, wait a few seconds to allow the
  353. echo cache to flush the buffers, and reboot...
  354.  
  355. :end
  356. if exist %1\ask.com del %1\ask.com >nul
  357.  
  358.